home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / src / exampleCode / irix / scripts / rcs / col-script < prev    next >
Encoding:
Text File  |  1994-08-02  |  3.6 KB  |  127 lines
  1. #! /bin/csh -f
  2. #
  3. # $Id: col-script,v 1.6 92/10/27 10:09:46 carlson Exp $
  4. #
  5. # col-script    Performs a co -l on the file passed and performs a
  6. #        diff on it and the version in ../src/hcrsgi.
  7. #
  8. #    Added functionality includes:
  9. #    1. Always performs default options $opt.
  10. #    2. Performs options found in environment variable RCSOPTS.
  11. #    3. Passes arguments from command line to co.
  12. #    4. Compares the file with the version in ../src/hcrsgi.
  13. #    5. Added option -i skips comparison of files.
  14. #    6. Performs options found in file .rcsopts.
  15. #
  16. # Revision History:
  17. #    $Log:    col-script,v $
  18. # Revision 1.6  92/10/27  10:09:46  carlson
  19. # When breaking out the options, break out three characters instead of
  20. #   just two to allow checking of just the character following the dash.
  21. # Remove default options that conflict with command line options.
  22. # 
  23. # Revision 1.5  92/01/22  15:21:53  carlson
  24. # No longer set the time of the file to that in the RCS file.
  25. # 
  26. # Revision 1.4  91/08/27  13:25:56  carlson
  27. # Fixed problems with handling new .rcsopts file.
  28. # 
  29. # Revision 1.3  91/08/27  13:11:59  carlson
  30. # Allow new style .rcsopts files.
  31. # Added comments.
  32. # 
  33. # Revision 1.2  91/07/29  09:01:33  chris
  34. # Cleaned up to use less code.  Doesn't separate option from argument
  35. #   anymore and then put them back together.
  36. # Added RCS symbols.
  37. # 
  38. #-----------------------------------------------------------------------
  39. # Set default options for co command here.
  40. #
  41. set opt = ( "-l" )
  42. if ( $?RCSOPTS ) then
  43.     set opt = ( $opt $RCSOPTS )
  44. endif
  45. if ( -e ./.rcsopts ) then
  46.     set x = ( `grep "^col[     ]" ./.rcsopts` )
  47.     if ( "$x" == "" ) set x = ( `grep "^co[     ]" ./.rcsopts` )
  48.     if ( $#x > 1 ) then
  49.     set opt = ( $opt $x[2-] )
  50.     else
  51.     set x = ( `cat ./.rcsopts` )
  52.     if ( "$x[1]" != "ci" ) then
  53.         echo "*** Old style .rcsopts file ***"
  54.         set opt = ( $opt `cat ./.rcsopts` )
  55.     endif
  56.     endif
  57. endif
  58. set ignore = 0
  59.  
  60. #----
  61. # Scan for end of options in parameter list.  We need to do this to
  62. # find where the file names start.
  63. #
  64. # While scanning, do the following:
  65. #    1. Remove any duplicated options from $opt.
  66. #    2. Check for -i option and set flag to remind us to check the
  67. #       differences in hcrsgi.
  68. #
  69. @ first = 1
  70.  
  71. while ( $first <= $#argv )
  72.     set arg_chars = ( `echo $argv[$first] | sed "s/\(.\)\(.\)\(.\)/\1 \2 \3/\\
  73. s/\(.\)\(.\)/\1 \2/"` )
  74.     if ( "$arg_chars[1]" != "-" ) break
  75.     if ( "$arg_chars[2]" == "-" ) then
  76.     set argv[$first]
  77.     break
  78.     endif
  79.     @ secnd = 1
  80.     while ( $secnd <= $#opt )
  81.     set opt_chars = ( `echo $opt[$secnd] | sed "s/\(.\)\(.\)\(.\)/\1 \2 \3/\\
  82. s/\(.\)\(.\)/\1 \2/"` )
  83.     if ( "$opt_chars[1]" != "-" ) break
  84.     if ( "$opt_chars[2]" == "$arg_chars[2]" ) set opt[$secnd]
  85.     if ( "$opt_chars[2]" == "u" && "$arg_chars[2]" == "l" ) \
  86.         set opt[$secnd]
  87.     if ( "$opt_chars[2]" == 'l' && "$arg_chars[2]" == "u" ) \
  88.         set opt[$secnd]
  89.     @ secnd = $secnd + 1
  90.     end
  91.     if ( "$argv[$first]" == "-i" ) then
  92.     set argv[$first]
  93.     set ignore = 1
  94.     endif
  95.     @ first=$first + 1
  96. end
  97.  
  98. #----
  99. # Check out files with arguments passed.
  100. #
  101. /usr/sbin/co $opt $argv
  102. if ( $status != 0 ) exit $status
  103. if ( $ignore == 1 ) exit 0
  104.  
  105. #----
  106. # Compare the differences between this version and the one in
  107. # ../src/hcrsgi.
  108. #
  109. if ( $first >= $#argv ) then
  110.     foreach arg ( $argv )
  111.     echo "----------------------------------$arg"
  112.     /bin/diff $arg ../src/hcrsgi/$arg
  113.     echo "----------------------------------$arg"
  114.     end
  115. else
  116.     @ first=$first + 1
  117.     foreach arg ( $argv[$first-] )
  118.     echo "----------------------------------$arg"
  119.     /bin/diff $arg ../src/hcrsgi/$arg
  120.     echo "----------------------------------$arg"
  121.     end
  122. endif
  123.  
  124. ### Local Variables:
  125. ### auto-fill-hook: nil
  126. ### End:
  127.